自作ソフト「時刻時間」を例に

[実践事例]

１　時計の目盛

TO めもり
RG HT
【説明／HT(かくれろ）を命令すると，円を描くスピードが少し速くなります。】
SETC 7 PU SETPOS [-200 30] MAKE "SUJI 12
【説明／時計の文字盤に書き込む数字を変数SUJIとして設定します。】
REPEAT 60 [PU FD 80 PD BK 0 PU BK 80 RT 6] SETC 5
【説明／時計の１分（１秒）ごとの目盛を描きます。】
REPEAT 12 [PU FD 80 PD LABEL :SUJI BK 0 PU BK 80 LT 30 MAKE "SUJI :SUJI - 1]
【説明／時計の文字盤に”１”から”１2”を書きます。】
END

２　長針・短針の表示

TO JIKAN :JI :HUN :BYOU
めもり
TELL [0 1 2] PU SETPOS [-200 30]
TELL 0 SETH :BYOU * 6 SETC 4 PD FD 70 BK 70
【説明／カメ０号に秒針を描かせます。】
TELL 1 SETH :HUN * 6 + :BYOU * 0.1 SETC 6 PD FD 60 BK 60
【説明／カメ１号に長針を描かせます。】
TELL 2 SETH :JI * 30 + :HUN * 0.5 + :BYOU * 0.5 * (1 / 60) SETC 6 PD FD 40 BK 40
【説明／カメ２号に短針を描かせます。】
END

３　３つの針が１秒間に回転する角度

TO 回転0
TONE 1200 1
TELL 0 PD FD 70
TELL 1 PD FD 60
TELL 2 PD FD 40
WAIT 60
TELL 0 PE BK 70 RT 6
【説明／秒針は６０秒で３６０度回転します。１秒間の回転角度は６度となります。】
TELL 1 PE BK 60 RT 0.1
【説明／長針は１分間に６度回転します。１秒間はその６／６０である０．１度回転します。】
TELL 2 PE BK 40 RT 0.5 / 60
【説明／短針は１時間に３０度（３６０／１２）回転します。
１分間に０．５度（３０／６０），１秒間には０．５／６０度回転します。】
回転0
【説明／繰り返し回転できるようにリカージョンを設定します。】
END

４　JIKAN 2 35 42（２時３５分４２秒・表示）

TO JIKAN :JI :HUN :BYOU
RG めもり
TELL [0 1 2] PU SETPOS [-200 30]
TELL 0 SETH :BYOU * 6 SETC 4 PD FD 70 BK 70
TELL 1 SETH :HUN * 6 + :BYOU * 0.1 SETC 6 PD FD 60 BK 60
TELL 2 SETH :JI * 30 + :HUN * 0.5 + :BYOU * 0.5 * (1 / 60) SETC 6 PD FD 40 BK 40
回転0
END

参考文献：LOGO WORLD10,LOGO WORLD11（LOGOJAPAN）